VB6: Kompilierte .exe immer im Vordergrund starten

  • VB6

Es gibt 15 Antworten in diesem Thema. Der letzte Beitrag () ist von wernho.

    VB6: Kompilierte .exe immer im Vordergrund starten

    Ich habe mir zwei Programme geschrieben, das eine ist eine Art von Lesezeichenverwaltung für die Internet-Browser, das andere eine Art Explorer-Aufrufer mit den Laufwerken und Ordnern, die ich am meisten brauche.
    Nun ist es aber so, dass wenn ich mehrere Fenster offen habe und eines der beiden aufrufe, dass diese nicht in den Vordergrund kommen, sondern ich mit Alt-Tab (1x) dorthin wechseln muss. Aufgerufen wird das mit einem Shortcut in meinem G900 Keyboard.

    Wie bitte kann ich es im Code bewerkstelligen, dass beim Aufruf der .exe dieses Programm immer im Vordergrund ist.

    Danke im Voraus.

    Puh, bei VB6 weiß ich es nicht genau, aber das ist eine Einstellung beim Fenster.
    Bei WinForms gibt's dafür die Eigenschaft ​TopMost.

    So unterschiedlich wird es dann nicht sein.
    Andererseits muss man dann auch wissen, dass das Fenster wirklich überall oben ist und nicht mehr in den Hintergrund gerückt werden kann.
    Quellcode lizensiert unter CC by SA 2.0 (Creative Commons Share-Alike)

    Meine Firma: Procyon Systems

    Selbstständiger Softwareentwickler & IT-Techniker.

    @wernho Aus meinem Archiv geholt. Dennoch ist das keine Garantie, das das Fenster immer TopMost bleibt.

    Visual Basic-Quellcode

    1. ​
    2. Option Explicit
    4. Private Declare Function SetWindowPos Lib "user32.dll" ( _
    5. ByVal hwnd As Long, _
    6. ByVal hWndInsertAfter As Long, _
    7. ByVal x As Long, _
    8. ByVal y As Long, _
    9. ByVal cx As Long, _
    10. ByVal cy As Long, _
    11. ByVal wFlags As Long) As Long
    13. Const SWP_NOMOVE = 2
    14. Const SWP_NOSIZE = 1
    15. Const SWP_WNDFLAGS = SWP_NOMOVE Or SWP_NOSIZE
    16. Const HWND_TOPMOST = -1
    17. Const HWND_NOTOPMOST = -2
    19. Private Sub Form_Load()
    20. SetWindowPos Me.hWnd, HWND_TOPMOST, 0, 0, 0, 0, SWP_WNDFLAGS
    21. End Sub
    Mfg -Franky-

    Danke schön für Eure Tipps.
    Leider ist genau dieser Code bereits enthalten, greift aber leider nicht. Das Fenster liegt des öfteren beim Aufruf an zweiter Stelle und muss mit 1x Alt-TAB geholt werden.
    Wenn es nicht gleich im Vordergrund ist, dann ist es immer an 2. Stelle (glaube ich zumindest).

    @wernho Dann hätte ich da nur noch was per Subclassing. Das hatte ich mal für ein OSK (OnScreenKeyboard) geschrieben das ja auch immer OnTop sein muss. Dazu brauchts ein Modul mit "Sub Main". In den Projekteigenschaften stellst halt anstelle der Form -> Sub Main ein.
    Spoiler anzeigen
    ​

    Visual Basic-Quellcode

    1. ​
    2. Option Explicit
    4. Private Const WS_EX_TOPMOST As Long = &H8
    5. Private Const WS_EX_NOACTIVATE As Long = &H8000000
    6. Private Const GWL_EXSTYLE As Long = -20
    7. Private Const GWL_WNDPROC As Long = -4
    8. Private Const HWND_TOPMOST As Long = -1
    9. Private Const SWP_NOSIZE As Long = &H1
    10. Private Const SWP_NOMOVE As Long = &H2
    11. Private Const SWP_NOACTIVATE As Long = &H10
    12. Private Const SW_SHOWNOACTIVATE As Long = 4
    13. Private Const WM_MOVING As Long = &H216
    14. Private Const WM_ACTIVATE As Long = &H6
    15. Private Const WM_ACTIVATEAPP As Long = &H1C
    17. Private Type RECT
    18. Left As Long
    19. Top As Long
    20. Right As Long
    21. Bottom As Long
    22. End Type
    24. Private Declare Function CallWindowProc Lib "user32" _
    25. Alias "CallWindowProcA" ( _
    26. ByVal lpPrevWndFunc As Long, _
    27. ByVal hwnd As Long, _
    28. ByVal Msg As Long, _
    29. ByVal wParam As Long, _
    30. ByVal lParam As Long) As Long
    32. Private Declare Function SetWindowLong Lib "user32" _
    33. Alias "SetWindowLongA" ( _
    34. ByVal hwnd As Long, _
    35. ByVal nIndex As Long, _
    36. ByVal dwNewLong As Long) As Long
    38. Private Declare Function GetWindowLong Lib "user32" _
    39. Alias "GetWindowLongA" ( _
    40. ByVal hwnd As Long, _
    41. ByVal nIndex As Long) As Long
    43. Private Declare Sub SetWindowPos Lib "user32" ( _
    44. ByVal hwnd As Long, _
    45. ByVal hWndInsertAfter As Long, _
    46. ByVal x As Long, _
    47. ByVal y As Long, _
    48. ByVal cx As Long, _
    49. ByVal cy As Long, _
    50. ByVal wFlags As Long)
    52. Private Declare Function ShowWindow Lib "user32" ( _
    53. ByVal hwnd As Long, _
    54. ByVal nCmdShow As Long) As Long
    56. Private Declare Sub CopyMemory Lib "kernel32" _
    57. Alias "RtlMoveMemory" ( _
    58. ByRef Destination As Any, _
    59. ByRef Source As Any, _
    60. ByVal Length As Long)
    62. Private tRect As RECT
    63. Private lngStyle As Long
    64. Private hFrmHwnd As Long
    65. Private lngOldWndProc As Long
    67. Sub Main()
    69. Load frmOSK '<- hier Deine Form
    71. hFrmHwnd = frmOSK.hwnd '<- hWnd von Deiner Form
    73. Call ShowWindow(hFrmHwnd, SW_SHOWNOACTIVATE)
    75. lngStyle = GetWindowLong(hFrmHwnd, GWL_EXSTYLE)
    76. lngStyle = lngStyle Or WS_EX_NOACTIVATE Or WS_EX_TOPMOST
    78. Call SetWindowLong(hFrmHwnd, GWL_EXSTYLE, lngStyle)
    80. Call SetWindowPos(hFrmHwnd, HWND_TOPMOST, 0&, 0&, 0&, 0&, SWP_NOSIZE Or _
    81. SWP_NOMOVE Or SWP_NOACTIVATE)
    83. lngOldWndProc = SetWindowLong(hFrmHwnd, GWL_WNDPROC, AddressOf WindowProc)
    85. End Sub
    87. Public Sub Unhook()
    89. Call SetWindowLong(hFrmHwnd, GWL_WNDPROC, lngOldWndProc)
    91. End Sub
    93. Private Function WindowProc(ByVal hwnd As Long, ByVal uMsg As Long, ByVal wParam As _
    94. Long, ByVal lParam As Long) As Long
    96. If uMsg = WM_MOVING Then
    98. Call CopyMemory(tRect, ByVal lParam, LenB(tRect))
    100. Call SetWindowPos(hFrmHwnd, -1, tRect.Left, tRect.Top, tRect.Right - _
    101. tRect.Left, tRect.Bottom - tRect.Top, 0&)
    103. WindowProc = True
    105. Exit Function
    107. End If
    109. If uMsg = WM_ACTIVATE Or uMsg = WM_ACTIVATEAPP Then
    111. Call SetWindowPos(hFrmHwnd, HWND_TOPMOST, 0&, 0&, 0&, 0&, SWP_NOSIZE Or _
    112. SWP_NOMOVE Or SWP_NOACTIVATE)
    114. End If
    116. WindowProc = CallWindowProc(lngOldWndProc, hwnd, uMsg, wParam, lParam)
    118. End Function


    Die "Sub Unhook()" rufst dann in Deinem Form_Unload auf. Ich muss aber dazu sagen das ich auf der Form keine Controls hatte und alle Button auf der Form gezeichnet wurden.
    Mfg -Franky-

    wernho schrieb:

    Aufgerufen wird das mit einem Shortcut in meinem G900 Keyboard

    Mich würde es nicht wundern, wenn in so einem Fall Windows selbst entscheidet, dass die Anwendung sich nicht einfach nach vorne morgeln darf. Ist das auch so, wenn du die Anwendung mit eigens ausgeführtem Klick startest?
    Besucht auch mein anderes Forum:
    Das Amateurfilm-Forum

    @-Franky-:
    Ich habe es mal neu kompiliert und werde nun den Befehl am Keyboard austauschen. Mal sehen, was passiert.
    edit:
    Also das Fenster bleibt immer im Vordergrund, da kann ich auch andere Fenster ansteuern, die kommen dann nicht. Aber das passt, denn wenn ich das aufrufe, dann wird dort sofort etwas getan. War noch nie anders. Somit ist das eine gute Lösung. Danke schön.

    @Marcus Gräfe:
    Muss ich erst mal schauen, denn es ist nicht immer so. Wenn ich beim nächsten Mal wieder mit dem Fenster hinten bin, werde ich es schließen und danach mittel Verknüpfung aufrufen.
    Die Verknüpfung ist im Startmenü und vom Keyboard wird es mittels Befehl aufgerufen. Heißt: Auf der Taste G4 am Keyboard (die Tastatur hat einige Zusatztasten) ist der Befehl zum Aufrufen hinterlegt: "E:/Dateien/VisualBasic/ExplorerAufrufen/ExplorerAufrufen.exe"
    edit:
    Hat sich somit erledigt, da die Lösung von @-Franky- funktioniert. Danke schön.

    Dieser Beitrag wurde bereits 3 mal editiert, zuletzt von „wernho“ ()

    @-Franky-:
    Ich muss zugeben, dass ich es nicht ganz verstehe.
    Ich habe zwar die Positionen gesehen (0, 0, 0, 0) und auch SWP_NOSIZE Or SWP_NOMOVE Or SWP_NOACTIVATE.
    Aber ich habe das Fenster normalerweise in der Mitte.
    Wie bitte kann ich das bewerkstelligen?

    edit:
    Großes Problem: ich habe Dropdowns in meiner Form, diese können nicht mehr benutzt werden, klappen nicht auf. :/

    Dieser Beitrag wurde bereits 1 mal editiert, zuletzt von „wernho“ ()

    wernho schrieb:

    Aber ich habe das Fenster normalerweise in der Mitte.

    Dazu kannst Du in der "Sub Main" einfach folgendes ändern.

    Visual Basic-Quellcode

    1. 'Call SetWindowPos(hFrmHwnd, HWND_TOPMOST, 0&, 0&, 0&, 0&, SWP_NOSIZE Or SWP_NOMOVE Or SWP_NOACTIVATE)
    2. Call SetWindowPos(hFrmHwnd, HWND_TOPMOST, 300&, 300&, 0&, 0&, SWP_NOSIZE Or SWP_NOACTIVATE)

    Die 300& ist hier nur als Beispiel für die Top/Left-Position der Form auf dem Screen.

    wernho schrieb:

    Großes Problem: ich habe Dropdowns in meiner Form, diese können nicht mehr benutzt werden, klappen nicht auf

    Das kann ich nicht nachvollziehen.
    Bilder

    • Test.png

      4,74 kB, 313×165, 36 mal angesehen
    Mfg -Franky-

    Danke, hat funktioniert.
    Und das mit den Dropdowns bin ich auch schon draufgekommen:
    sie klappen zwar auf, sind aber hinter der Form. Bin auch nur deswegen draufgekommen, weil ich eines der unteren angeklickt habe.
    Screenshot:

    @wernho Du kannst auch hier Bilder/Anhänge hochladen. Das geht über "Erweiterte Antwort". Hmm, wenn ich mir Dein Bild so anschau, sind das die Standard-Comboboxen von VB6, machst Du ein Ownerdraw auf die Comboboxen oder sind das Drittanbieter-Controls? Weil der Button zum aufklappen der Combobox ist schmaler und hat eine andere Farbe.
    Mfg -Franky-

    Danke, ich habe es nicht gefunden, wo ich Bilder einfügen kann. Normalerweise bin ich nicht so unbedarft ;)

    Ja, es ist ein Drittanbieter, ich habe mir vor längerer Zeit schon die sev-Development Tools gekauft.
    Und ich habe eine normale Combobox testweise eingebaut, und diese funktioniert.
    Ok, muss ich mit etwas einfallen lasse: entweder ich baue das ganze um auf normale Comboboxen oder ich muss eine Lösung für meine Comboboxen finden.

    Und vielen lieben Dank für Deine Bemühungen und die Zeit, die Du mir geopfert hast.

    Hi @wernho
    ich kenne das Problam aus meinen VB6 Zeiten und habe vor 25 Jahren eine Lösung dafür gebaut.
    Habe ewig daran gefummelt.
    Ich schaue haute Abend mal nach dem alten Code und poste dir dann die Lösung, wenn ich den Code noch finde.
    Es war iegendwie was, mit manuellem Legen des Fensters ganz oben auf den Stapel der offenen Fenstern, wenn ich mich recht erinnere...

    EDIT: Ah, meine Anwot hat sich erledigt - Franky hat ja schon den Weg gewiesen... ;)

    So, jetzt ist es erledigt.
    Genau das, was @-Franky-/Ihr mir beschrieben habt, habe ich nun auch auf der Seite von vb@rchive, wo ich die Zusatzkomponenten gekauft habe, gefunden.
    Dort wird das ganze mit einer Function aufgerufen: FormOnTop. Das Ganze mit dem Parameter True or False.
    Zwar bleibt mir, wenn ich auf True gehe, auch meine eigenen Comboboxen im Hintergrund, ABER: wenn ich sofort danach das Ganze auf False setze, sind die Comboboxen wieder zur Gänze sichtbar.
    Also rufe ich das Ganze mit True auf, bringe somit das Fenster in den Vordergrund und gleich danach auf False, Fenster bleibt im Vordergrund und meine Comboboxen sind sichtbar.

    Ich danke Euch recht herzlich, denn Ihr habt mich auf den richtigen Weg gebracht, jetzt funktioniert es.