CreateCompatibleDC + SetPixel -> BitBlt

Mad Andy · 25. Oktober 2007, 11:13

Hi!

Folgender Ablauf:
Ich hab 4 Bilder, die per SetPixel gezeichnet werden. Dise sollen aber in getrennte DCs gepackt werden, weil das Neuzeichnen zu lange dauert (-> flackern), und dann per BitBlt in eine Picturebox gebltet werden.

Mein bisheriger Code:

APIs, UDTs und Consts:

Visual Basic-Quellcode

Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (Destination As Any, Source As Any, ByVal Length As Long)
Private Declare Function GetDC Lib "user32" (ByVal hWnd As Long) As Long
Private Declare Function CreateCompatibleDC Lib "gdi32" (ByVal hDC As Long) As Long
Private Declare Function DeleteDC Lib "gdi32" (ByVal hDC As Long) As Long
Private Declare Function SetPixel Lib "gdi32" (ByVal hDC As Long, ByVal x As Long, ByVal y As Long, ByVal crColor As Long) As Long
Private Declare Function BitBlt Lib "gdi32" (ByVal hDestDC As Long, ByVal x As Long, ByVal y As Long, ByVal nWidth As Long, ByVal nHeight As Long, ByVal hSrcDC As Long, ByVal xSrc As Long, ByVal ySrc As Long, ByVal dwRop As Long) As Long
Private Declare Function GetPixel Lib "gdi32" (ByVal hDC As Long, ByVal x As Long, ByVal y As Long) As Long
Private Type COLORREF
rgbRed As Byte
rgbGreen As Byte
rgbBlue As Byte
rgbReserved As Byte
End Type
Private Const SRCCOPY = &HCC0020 ' (DWORD) dest = source

Programm:

Visual Basic-Quellcode

'Bildauswahl
Private cSel As Byte 'Farbe: cGn
Private cSelOld As Byte 'zur Änderungsprüfung
Private cmdDown As Boolean 'Farbe:cCn
Private cmdDownOld As Boolean 'zur Änderungsprüfung
'Farbwerte (Anfang & Ende von Verlauf)
Private cG1 As COLORREF
Private cG2 As COLORREF
Private cC1 As COLORREF
Private cC2 As COLORREF
'DCs
Private hDCn As Long 'normal
Private hDCh As Long 'hover
Private hDCnd As Long 'normal, down
Private hDChd As Long 'hover, down
Private Sub Form_Load()
cG1 = NewColor(225, 222, 213)
cG2 = NewColor(179, 176, 170)
cC1 = NewColor(173, 201, 237)
cC2 = NewColor(130, 151, 179)
cSel = 0
cSelOld = 1
cmdDown = False
cmdDownOld = True
hDCn = CreateCompatibleDC(GetDC(0))
hDCh = CreateCompatibleDC(GetDC(0))
hDCnd = CreateCompatibleDC(GetDC(0))
hDChd = CreateCompatibleDC(GetDC(0))
picBG_Resize
End Sub
Private Sub picBG_Resize()
DrawNiceButton hDCn, cG1, cG2, picBG.Width / 15, picBG.Height / 15, False
DrawNiceButton hDCh, cC1, cC2, picBG.Width / 15, picBG.Height / 15, False
DrawNiceButton hDCnd, cG1, cG2, picBG.Width / 15, picBG.Height / 15, True
DrawNiceButton hDChd, cC1, cC2, picBG.Width / 15, picBG.Height / 15, True
End Sub
Private Sub DrawNiceButton(hDC As Long, cStart As COLORREF, cEnd As COLORREF, Width As Long, Height As Long, Pressed As Boolean)
'Debug-Output liefert gültige DCs und die richtigen Werte
Debug.Print "DrawNiceButton: hDC=" & hDC & ", cStart=(" & cStart.rgbRed & ", " & cStart.rgbGreen & ", " & cStart.rgbBlue & "), cEnd=(" & cEnd.rgbRed & ", " & cEnd.rgbGreen & ", " & cEnd.rgbBlue & "), width=" & Width & ", height=" & Height & ", pressed=" & Pressed
'...
'cThis hat den richtigen Wert, gleicher Code hat mit picBG.hDC funktioniert
cThis = BalanceColor(cRowStart, cRowEnd, CSng(y) / ymax)
CopyMemory lThis, cThis, 4
SetPixel hDC, x, y, lThis
'...
End Sub
Private Sub picBG_Paint()
If cmdDown Then
If cSel = 0 Then
BitBlt picBG.hDC, 0, 0, picBG.Width / 15 - 1, picBG.Height / 15 - 1, hDCnd, 0, 0, SRCCOPY
Else
BitBlt picBG.hDC, 0, 0, picBG.Width / 15 - 1, picBG.Height / 15 - 1, hDChd, 0, 0, SRCCOPY
End If
Else
If cSel = 0 Then
Debug.Print BitBlt(picBG.hDC, 0, 0, picBG.Width / 15 - 1, picBG.Height / 15 - 1, hDCn, 0, 0, SRCCOPY)
Else
BitBlt picBG.hDC, 0, 0, picBG.Width / 15 - 1, picBG.Height / 15 - 1, hDCh, 0, 0, SRCCOPY
End If
End If
End Sub

BitBlt gibt 1 zurück -> scheinbar kein Fehler.

Wenn ich mit

Visual Basic-Quellcode

lThis = GetPixel(hDCn, x, y)
CopyMemory cThis, lThis, 4

einen beliebigen Punkt vom "normal"-DC augebe, kommt immer 255, 255, 255.

Hab ich vllt. irgendwas vergessen? Muss man irgendeine Region o.Ä. bei nem eigenen DC setzen?

so long..
Andy

Mad Andy · 26. Oktober 2007, 11:59

Weiß echt niemand was?
Irgedein Ansatz, was ich vergessen haben könnte würde mir schon weiterhelfen ...

Lupus · 26. Oktober 2007, 15:03

was is da immer mit den Doppel-posts?

Sorry, ich bin vb2005er...

Mad Andy · 26. Oktober 2007, 21:07

1. ist das pushen, und nicht doppelposten
2. hab ich da nach irgendnem ansatz gefragt.. (vorher hab ich nach ner lösung gefragt)
3. irgendjemand hier im board kennt sich mit DCs ein bisschen aus, ich weiß aber nicht mehr wer

Unknown · 30. Oktober 2007, 20:12

Du bist kein unbeschriebenes Blatt in Sachen Programmierung,
da hättest du ruhig wissen können, dass man zuerst in
die MSDN guckt!

Egal. Das Problem ist, dass CreateCompatibleDC nur einen
- wie der Name schon sagt - kompatiblen Gerätekontext
anlegt, keine Kopie. Deshalb ist dein DC nur einen Pixel
breit, einen Pixel hoch und monochrom. Du musst den
DC also mit einer Bitmap dimensionieren. Achte dabei darauf,
dass du eine Bitmap erstellst, die kompatibel zu dem
Bildschirm ist, ansonsten bleibt der DC monochrom.

Übrigens kannst du dir das GetDC(0) beim erstellen
des DCs sparen, da die Übergabe von 0 als Parameter
den gleichen Effekt hat.

Mad Andy · 31. Oktober 2007, 03:37

War ja klar, dass du das wieder weißt

Scheinbar is die Mail doch nicht ins Nirvana geliefert worden

Werds morgen gleich ausprobieren, danke.

Das mit der MSDN stimmt eigentlich, auf msdn.microsoft.com findet man aber nix mehr und die 1998er, die ich hier rumliegen hab, hab ich noch nich oben..

so long..
Andy

Mad Andy · 31. Oktober 2007, 12:56

Brauch ich außer CreateCompatibleBitmap und DeleteObject noch was?

einfach nur

Visual Basic-Quellcode

CreateCompatibleBitmap(hdc, Width, Height)

in DrawNiceButton reinzupacken hat nix geholfen. Wenn das DC kompatibel zum Screen ist (was es ja durch den Parameter 0 (= vom Programm übernehmen) sein sollte), müsste die Bitmap doch genauso kompatibel sein?

Gibts sonst noch was? :-\

Unknown · 31. Oktober 2007, 19:22

Was ist hdc ? Dein gerade mit CreateCompatibleDC
erstelltes DC ? Wenn ja: Da muss der DC des Bildschirms
hin. (Leider kann man hier nicht einfach 0 übergeben)

Die Bitmap ist Kompatibel zum Bildschirm, wenn du
dein erstelltes DC verwendest, allerdings werden
auch die Farbinformationen von deinem DC übernommen,
wodurch dein DC monochrom bleiben würde.

Und ja, du musst die Bitmap noch mit SelectObject in
den DC selektieren.

Mad Andy · 31. Oktober 2007, 23:17

Ja, hDC ist das eben erstellte DC.
Und wie bringe ich die Bitmap dann dazu, dass sie kompatibel ist? Also was muss ich als hDC übergeben?

Unknown · 1. November 2007, 16:22

Wie gesagt:
Der DC vom Bildschirm (GetDC(0)).

Mad Andy · 15. November 2007, 12:58

Bin jetzt endlich damit fertig geworden

picBG ist die Picturebox, die als Button dient. (Der Name ist so, weil da noch ein Label, ein Icon, etc.. rein kommt)

Ich verwende zur Farbwahl eine Struct, die in C++ dafür verwendet wird: COLORREF. In VB6 kann man diese leider nicht an SetPixel übergeben. Mit CopyMemory stopf ich das also erst in einen Long, bevor ichs zeichne.

APIs, Structs, Consts:

Visual Basic-Quellcode

Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (Destination As Any, Source As Any, ByVal Length As Long)
Private Declare Function GetDC Lib "user32" (ByVal hWnd As Long) As Long
Private Declare Function CreateCompatibleDC Lib "gdi32" (ByVal hDC As Long) As Long
Private Declare Function CreateCompatibleBitmap Lib "gdi32" (ByVal hDC As Long, ByVal nWidth As Long, ByVal nHeight As Long) As Long
Private Declare Function DeleteDC Lib "gdi32" (ByVal hDC As Long) As Long
Private Declare Function SelectObject Lib "gdi32" (ByVal hDC As Long, ByVal hObject As Long) As Long
Private Declare Function DeleteObject Lib "gdi32" (ByVal hObject As Long) As Long
Private Declare Function SetPixel Lib "gdi32" (ByVal hDC As Long, ByVal X As Long, ByVal Y As Long, ByVal crColor As Long) As Long
Private Declare Function BitBlt Lib "gdi32" (ByVal hDestDC As Long, ByVal X As Long, ByVal Y As Long, ByVal nWidth As Long, ByVal nHeight As Long, ByVal hSrcDC As Long, ByVal xSrc As Long, ByVal ySrc As Long, ByVal dwRop As Long) As Long
Private Type COLORREF
rgbRed As Byte
rgbGreen As Byte
rgbBlue As Byte
rgbReserved As Byte
End Type
Private Const SRCCOPY = &HCC0020 ' (DWORD) dest = source

Variablen:

Visual Basic-Quellcode

'Colors
Private cG1 As COLORREF 'Gray color 1
Private cG2 As COLORREF 'Gray color 2
Private cC1 As COLORREF 'Active color 1
Private cC2 As COLORREF 'Active color 2
'State
Private cSel As Byte 'Active or Gray?
Private cSelOld As Byte 'Helper to see if we have to redraw it
Private cmdDown As Boolean 'Down ("Pressed") or not?
Private cmdDownOld As Boolean 'Helper to see if we have to redraw it
'DCs and BMPs
Private hDCn As Long 'normal
Private hDCh As Long 'hover
Private hDCnd As Long 'normal, down
Private hDChd As Long 'hover, down
Private hBMPn As Long 'normal
Private hBMPh As Long 'hover
Private hBMPnd As Long 'normal, down
Private hBMPhd As Long 'hover, down

General Functions:

Visual Basic-Quellcode

Private Function NewColor(r As Byte, g As Byte, b As Byte) As COLORREF
'Creates a new color with single R, G and B values
NewColor.rgbRed = r
NewColor.rgbGreen = g
NewColor.rgbBlue = b
End Function
Private Function BalanceColor(c1 As COLORREF, c2 As COLORREF, Balance As Single) As COLORREF
'Balances a color between 2 colors with a given ratio
BalanceColor.rgbBlue = c1.rgbBlue * (1 - Balance) + c2.rgbBlue * Balance
BalanceColor.rgbGreen = c1.rgbGreen * (1 - Balance) + c2.rgbGreen * Balance
BalanceColor.rgbRed = c1.rgbRed * (1 - Balance) + c2.rgbRed * Balance
End Function

Program:

Visual Basic-Quellcode

Private Sub Form_Load()
'Set colors
cG1 = NewColor(225, 222, 213)
cG2 = NewColor(179, 176, 170)
cC1 = NewColor(173, 201, 237)
cC2 = NewColor(130, 151, 179)
'Set state
cSel = 0
cSelOld = 1
cmdDown = False
cmdDownOld = True
'Create and draw the DCs
picBG_Resize
End Sub
Private Sub Form_Unload(Cancel As Integer)
'Delete DCs and BMPs
DeleteDC hDCn
DeleteDC hDCh
DeleteDC hDCnd
DeleteDC hDChd
DeleteObject hBMPn
DeleteObject hBMPh
DeleteObject hBMPnd
DeleteObject hBMPhd
End Sub
Private Sub Form_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
cSel = 0 'Hover = false
PaintCmd 'Check if we have to repaint it
End Sub
Private Sub picBG_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
cSel = 1 'Hover = true
PaintCmd 'Check if we have to repaint it
End Sub
Private Sub picBG_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
cmdDown = True 'Pressed = true
PaintCmd 'Check if we have to repaint it
End Sub
Private Sub picBG_MouseUp(Button As Integer, Shift As Integer, X As Single, Y As Single)
cmdDown = False 'Pressed = false
PaintCmd 'Check if we have to repaint it
End Sub

Drawing:

Visual Basic-Quellcode

Private Sub PaintCmd()
'We do the repaint check here because the redraw event
'is used for "general" redraw (via win msg) too.
'If hover changed -> redraw
If cSelOld <> cSel Then
cSelOld = cSel
picBG_Paint
End If
'If down-state changed -> redraw
If cmdDownOld <> cmdDown Then
cmdDownOld = cmdDown
picBG_Paint
End If
End Sub
Private Sub picBG_Paint()
'Copy the matching DC to our picBox via BitBlt.
If cmdDown Then
If cSel = 0 Then
BitBlt picBG.hDC, 0, 0, picBG.Width \ 15, picBG.Height \ 15, hDCnd, 0, 0, SRCCOPY
Else
BitBlt picBG.hDC, 0, 0, picBG.Width \ 15, picBG.Height \ 15, hDChd, 0, 0, SRCCOPY
End If
Else
If cSel = 0 Then
BitBlt picBG.hDC, 0, 0, picBG.Width \ 15, picBG.Height \ 15, hDCn, 0, 0, SRCCOPY
Else
BitBlt picBG.hDC, 0, 0, picBG.Width \ 15, picBG.Height \ 15, hDCh, 0, 0, SRCCOPY
End If
End If
End Sub

Creation:

Visual Basic-Quellcode

Private Sub picBG_Resize()
'We have to recreate and redraw the button's DCs when the size changed
DrawNiceButton hDCn, hBMPn, cG1, cG2, picBG.Width / 15, picBG.Height / 15, False
DrawNiceButton hDCh, hBMPh, cC1, cC2, picBG.Width / 15, picBG.Height / 15, False
DrawNiceButton hDCnd, hBMPnd, cG1, cG2, picBG.Width / 15, picBG.Height / 15, True
DrawNiceButton hDChd, hBMPhd, cC1, cC2, picBG.Width / 15, picBG.Height / 15, True
End Sub
Private Sub DrawNiceButton(hDC As Long, hBMP As Long, cStart As COLORREF, cEnd As COLORREF, Width As Long, Height As Long, Pressed As Boolean)
'Delete the old DC and the old BMP
If hDC > 0 Then DeleteDC hDC
If hBMP > 0 Then DeleteObject hBMP
'CreateCompatibleDC
hDC = CreateCompatibleDC(GetDC(0))
If hDC = 0 Then
Debug.Print "CreateCompatibleDC failed!"
Exit Sub
End If
'CreateCompatibleBitmap
hBMP = CreateCompatibleBitmap(GetDC(0), Width, Height)
If hBMP = 0 Then
Debug.Print "CreateCompatibleBitmap failed!"
Exit Sub
End If
'Select the BMP to the DC
If SelectObject(hDC, hBMP) = 0 Then
Debug.Print "Selectobject failed!"
Exit Sub
End If
'Colors
' cStart and cEnd are the color values for two of the corners, cMid for the other two.
' cRowStart contains the color value for the first px in the row, cRowEnd for the
' last px in the row.
' cThis and lThis contains the color values for the current pixel.
Dim cMid As COLORREF
Dim cRowStart As COLORREF
Dim cRowEnd As COLORREF
Dim cThis As COLORREF
Dim lThis&
'Counter vars
Dim X&, Y&
Dim xmax&, ymax&
'Set the counter maximums
xmax = Width - 1
ymax = Height - 1
'Get the color for 2 of the corners
cMid = BalanceColor(cStart, cEnd, 0.5)
'Pressed buttons are drawn bottom-up
If Pressed Then
For X = 0 To xmax
cRowStart = BalanceColor(cStart, cMid, CSng(X) / xmax)
cRowEnd = BalanceColor(cMid, cEnd, CSng(X) / xmax)
For Y = 0 To ymax
cThis = BalanceColor(cRowStart, cRowEnd, CSng(Y) / ymax)
CopyMemory lThis, cThis, 4
SetPixel hDC, X, ymax - Y, lThis
Next Y
Next X
Else
For X = 0 To xmax
cRowStart = BalanceColor(cStart, cMid, CSng(X) / xmax)
cRowEnd = BalanceColor(cMid, cEnd, CSng(X) / xmax)
For Y = 0 To ymax
cThis = BalanceColor(cRowStart, cRowEnd, CSng(Y) / ymax)
CopyMemory lThis, cThis, 4
SetPixel hDC, X, Y, lThis
Next Y
Next X
End If
End Sub

Wenns fragen dazu gibt, einfach melden

so long..
Andy

CreateCompatibleDC + SetPixel -> BitBlt

CreateCompatibleDC + SetPixel -> BitBlt

Visual Basic-Quellcode

Visual Basic-Quellcode

Visual Basic-Quellcode

Visual Basic-Quellcode

Visual Basic-Quellcode

Visual Basic-Quellcode

Visual Basic-Quellcode

Visual Basic-Quellcode

Visual Basic-Quellcode

Visual Basic-Quellcode

Ähnliche Themen

2 Benutzer haben hier geschrieben